Meson build: Use Meson's pkgconfig module

kjellahl · kjellahl · commit d4389e1e012a · 2024-07-15T13:37:49.000+02:00
instead of using the libxml++.pc.in template.
Require meson &gt;= 0.62. Remove the can_add_dist_script variable.
It's unnecessary when the meson version &gt;= 0.58.
diff --git a/docs/manual/meson.build b/docs/manual/meson.build
@@ -1,7 +1,7 @@
 # docs/manual
 
 # input: install_datadir, xmlxx_pcname, tutorial_custom_cmd_py, python3,
-#        build_documentation, book_name, can_add_dist_script, xsltproc
+#        build_documentation, book_name, xsltproc
 # output: can_parse_and_validate, build_pdf_by_default, can_build_pdf,
 #         install_tutorialdir, build_manual_opt, build_manual
 
@@ -106,13 +106,11 @@ if can_build_pdf
   )
 endif
 
-if can_add_dist_script
-  # Distribute built files.
-  meson.add_dist_script(
-    python3, tutorial_custom_cmd_py, 'dist_doc',
-    doc_dist_dir,
-    meson.current_build_dir(),
-    meson.current_build_dir() / 'libxml++.xml',
-    meson.current_build_dir() / 'libxml++.pdf',
-  )
-endif
+# Distribute built files.
+meson.add_dist_script(
+  python3, tutorial_custom_cmd_py, 'dist_doc',
+  doc_dist_dir,
+  meson.current_build_dir(),
+  meson.current_build_dir() / 'libxml++.xml',
+  meson.current_build_dir() / 'libxml++.pdf',
+)
diff --git a/docs/reference/meson.build b/docs/reference/meson.build
@@ -2,7 +2,7 @@
 
 # Input: project_build_root, project_source_root, xmlxx_pcname,
 #        xmlxx_api_version, build_documentation, source_h_files,
-#        install_datadir, python3, doc_reference_py, can_add_dist_script, dot
+#        install_datadir, python3, doc_reference_py, dot
 # Output: install_docdir, install_devhelpdir, book_name,
 #         if build_documentation: tag_file
 
@@ -128,14 +128,12 @@ meson.add_install_script(
   docinstall_flags
 )
 
-if can_add_dist_script
-  # Distribute built files and files copied by mm-common-get.
-  meson.add_dist_script(
-    python3, doc_reference_py, 'dist_doc',
-    doctool_dir,
-    doctool_dist_dir,
-    meson.current_build_dir(),
-    tag_file.full_path(),
-    devhelp_file.full_path(),
-  )
-endif
+# Distribute built files and files copied by mm-common-get.
+meson.add_dist_script(
+  python3, doc_reference_py, 'dist_doc',
+  doctool_dir,
+  doctool_dist_dir,
+  meson.current_build_dir(),
+  tag_file.full_path(),
+  devhelp_file.full_path(),
+)
diff --git a/libxml++/meson.build b/libxml++/meson.build
@@ -1,7 +1,8 @@
 # libxml++
 
 # Input: xmlxx_build_dep, xmlxx_pcname, xmlxx_libversion, xmlxx_api_version,
-#        install_includedir, xmlxx_rc, xmlxx_libname, macos_darwin_versions
+#        install_includedir, xmlxx_rc, xmlxx_libname, macos_darwin_versions,
+#        xmlxx_pc_requires, libxml2_lib_pkgconfig
 # Output: source_h_files, xmlxx_own_dep
 
 # There are no built source files in libxml++-5.0.
@@ -116,6 +117,35 @@ xmlxx_library = library(xmlxx_libname,
   install: true,
 )
 
+# Generate .pc files, used by pkg-config.
+pkg_config = import('pkgconfig')
+pc_common_variables = [
+  'doxytagfile=${docdir}/reference/' + xmlxx_pcname + '.tag',
+  'htmlrefdir=${docdir}/reference/html',
+  'htmlrefpub=https://libxmlplusplus.github.io/libxmlplusplus/reference/html',
+]
+pc_variables = [
+  'exec_prefix=${prefix}',
+  'datarootdir=${datadir}',
+  'docdir=${datadir}/doc/' + xmlxx_pcname,
+] + pc_common_variables
+pc_uninstalled_variables = [
+  'docdir=${prefix}/docs',
+] + pc_common_variables
+
+pkg_config.generate(xmlxx_library,
+  filebase: xmlxx_pcname,
+  variables: pc_variables,
+  uninstalled_variables: pc_uninstalled_variables,
+  name: meson.project_name(),
+  description: 'C++ wrapper for libxml2',
+  url: 'https://libxmlplusplus.github.io/libxmlplusplus/',
+  requires: xmlxx_pc_requires,
+  libraries: libxml2_lib_pkgconfig,
+  subdirs: [xmlxx_pcname],
+  extra_cflags: ['-I${libdir}/' + xmlxx_pcname + '/include'],
+)
+
 # This is used when building example programs and test programs.
 # It's also a part of xmlxx_dep, when libxml++ is a subproject.
 xmlxx_own_dep = declare_dependency(
diff --git a/meson.build b/meson.build
@@ -7,7 +7,7 @@ project('libxml++', 'cpp',
     'warning_level=1',
     'cpp_std=c++17',
   ],
-  meson_version: '>= 0.60.0', # required for dependency('iconv')
+  meson_version: '>= 0.62.0', # required for variables in pkgconfig.generate()
 )
 
 xmlxx_api_version = '5.0'
@@ -113,22 +113,20 @@ xml2_dep = dependency(
   fallback: ['libxml2']
 )
 
-xmlxx_requires = []
-libxml2_lib_pkgconfig = ''
+xmlxx_pc_requires = []
+libxml2_lib_pkgconfig = []
 
 # Put libxml-2.0 in the 'Requires:' section in the generated pkg-config file if
 # we found it by pkg-config
 if xml2_dep.type_name() == 'pkgconfig' or xml2_dep.type_name() == 'internal'
-  xmlxx_requires += ['libxml-2.0', xml2_req]
+  xmlxx_pc_requires += ['libxml-2.0' + xml2_req]
 else
-  libxml2_lib_pkgconfig = xml2_dep.get_variable(
+  libxml2_lib_pkgconfig += [xml2_dep.get_variable(
     cmake:         'LIBXML2_LIBRARIES',
     default_value: 'LibXml2.lib',
-  )
+  )]
 endif
 
-xmlxx_requires = ' '.join(xmlxx_requires)
-
 # Make sure we link to libxml-2.0
 xmlxx_build_dep = [xml2_dep]
 
@@ -270,20 +268,8 @@ endif
 
 # Configure files
 pkg_conf_data = configuration_data()
-pkg_conf_data.set('prefix', install_prefix)
-pkg_conf_data.set('exec_prefix', '${prefix}')
-pkg_conf_data.set('libdir', '${exec_prefix}' / install_libdir)
-pkg_conf_data.set('datarootdir', '${prefix}' / install_datadir)
-pkg_conf_data.set('datadir', '${datarootdir}')
-pkg_conf_data.set('includedir', '${prefix}' / install_includedir)
 pkg_conf_data.set('PACKAGE_NAME', meson.project_name()) # MSVC_NMake/libxml++/libxml++.rc
-pkg_conf_data.set('PACKAGE_TARNAME', meson.project_name())
 pkg_conf_data.set('PACKAGE_VERSION', meson.project_version())
-pkg_conf_data.set('LIBXMLXX_MODULE_NAME', xmlxx_pcname)
-pkg_conf_data.set('LIBXMLXX_API_VERSION', xmlxx_api_version)
-pkg_conf_data.set('LIBXMLXX_MODULES', xmlxx_requires)
-pkg_conf_data.set('LIBXML2_LIB_NO_PKGCONFIG', libxml2_lib_pkgconfig)
-pkg_conf_data.set('MSVC_TOOLSET_VER', msvc14x_toolset_ver)
 
 if not build_deprecated_api
   pkg_conf_data.set('LIBXMLXX_DISABLE_DEPRECATED', 1)
@@ -308,13 +294,6 @@ if cpp_compiler.get_argument_syntax() == 'msvc'
   endif
 endif
 
-configure_file(
-  input: 'libxml++.pc.in',
-  output: xmlxx_pcname + '.pc',
-  configuration: pkg_conf_data,
-  install_dir: install_pkgconfigdir,
-)
-
 xmlxxconfig_h_meson = files('libxml++config.h.meson')
 install_includeconfigdir = install_libdir / xmlxx_pcname / 'include'
 configure_file(
@@ -324,36 +303,31 @@ configure_file(
   install_dir: install_includeconfigdir,
 )
 
-# add_dist_script() is not allowed in a subproject if meson.version() < 0.58.0.
-can_add_dist_script = not meson.is_subproject() or meson.version().version_compare('>= 0.58.0')
-
 subdir('MSVC_NMake/libxml++')
 subdir('libxml++')
 subdir('examples')
 subdir('tests')
 subdir('docs/reference')
 subdir('docs/manual')
 
-if can_add_dist_script
-  # Add a ChangeLog file to the distribution directory.
-  meson.add_dist_script(
-    python3, dist_changelog_py,
-    project_source_root,
-  )
+# Add a ChangeLog file to the distribution directory.
+meson.add_dist_script(
+  python3, dist_changelog_py,
+  project_source_root,
+)
 
-  # Don't distribute these files and directories.
-  dont_distribute = [
-    '.github',
-  ]
-  # Add build scripts to the distribution directory, and delete .gitignore
-  # files and an empty $MESON_PROJECT_DIST_ROOT/build/ directory.
-  meson.add_dist_script(
-    python3, dist_build_scripts_py,
-    project_source_root,
-    'untracked' / 'build_scripts',
-    dont_distribute,
-  )
-endif
+# Don't distribute these files and directories.
+dont_distribute = [
+  '.github',
+]
+# Add build scripts to the distribution directory, and delete .gitignore
+# files and an empty $MESON_PROJECT_DIST_ROOT/build/ directory.
+meson.add_dist_script(
+  python3, dist_build_scripts_py,
+  project_source_root,
+  'untracked' / 'build_scripts',
+  dont_distribute,
+)
 
 if meson.is_subproject()
   pkgconfig_vars = {
